ÿþ          ----
ENGLISH VERSION
       -------

`Project Method: PlugInRegistration
`Call On Startup to get the key that matches the current 4D environment
`And register the plugin with the returned key

`Syntax:
`C_TEXT($key)
`C_LONGINT($result)
`$key:=PlugInRegistration ("My key 1";"My key 2"; &  ; "My key n")
`$result:=$XX_Register($key)


C_TEXT(${1})`All your license keys for the plugin
C_TEXT($0)`The key that matches the current setup

C_LONGINT($serialKey;$connectedUsers;$maxUsers;$loop)
C_STRING(80;$currentUser)
C_STRING(80;$companyName)

GET SERIAL INFORMATION($serialKey;$currentUser;$companyName;$connectedUsers;$maxUsers)`only the serial key matters here

$0:="No key received for "+String($serialKey)`return an error message with the current 4D Serial

For ($loop;1;Count parameters)`test all keys until we get the good one
	If (Position(String($serialKey);${$loop})>0) `the 4D serial number is part of the plugin registration key
		$0:=${$loop}`return the proper key
		$loop:=Count parameters`no need to pursue
	End if 
End for 


          ----
FRENCH VERSION
       -------

`Méthode projet: PlugInRegistration
`Appeler Sur Ouverture pour récupérer la clé d enregistrement
`correspondant à l environnement 4D utilisé
`Puis sérialiser le plug-in avec la clé retournée

`Syntaxe:
`C_TEXTE($clé)
`C_ENTIER LONG($résultat)
`$clé:=PlugInRegistration ("Ma clé 1";"Ma clé 2"; &  ; "Ma clé n")
`$résultat:=XX_Register($clé)


C_TEXTE(${1})`Toutes vos clés d enregistrement pour le plug-in
C_TEXTE($0)`La clé correspondant à l environnement 4D utilisé 

C_ENTIER LONG($numéro4D;$utilisateursConnectés;$utilisateursMaxi;$boucle)
C_ALPHA(80;$utilisateurCourant)
C_ALPHA(80;$société)

LIRE INFORMATIONS SERIALISATION($numéro4D;$utilisateurCourant;$société;$utilisateursConnectés;$utilisateursMaxi)`seul le numéro 4D nous intéresse ici

$0:="Aucune clé trouvée pour "+Chaine($numéro4D)`retourne un message d erreur contenant le numéro 4D

Boucle ($boucle;1;Nombre de parametres)`teste toutes les clés jusqu à trouver la bonne
	Si (Position(Chaine($numéro4D);${$boucle})>0)`le numéro 4D est contenu dans la clé d enregistrement du plug-in
		$0:=${$boucle}`retourne la clé recherchée
		$boucle:=Nombre de parametres`inutile de continuer
	Fin de si 
Fin de boucle